Tabellen - Felddatentyp

Welchen Felddatentyp besitzt das Tabellenfeld?

Wenn man prüfen will, ob das Feld bereits den erforderlichen Felddatentyp besitzt sollte man folgende Funktion verwenden. Als Rückgabe erhält man eine Zahl, die man über eine Case-Schleife auflösen und den Datentyp zuordnen kann. Mehr Infos erhalten Sie über die Online-Hilfe.

DAO-Variante

Beispiel:

Public Function DAO_CheckFieldType(pdbs As DAO.Database, _
                                   ByVal psTable As String, _
                                   ByVal psField As String) As Long
 
  On Error GoTo HandleErr
  DAO_CheckFieldType = pdbs.TableDefs(psTable).Fields(psField).Type
 
HandleExit:
  Exit Function
 
HandleErr:
  Select Case Err.Number
    Case Else
      MsgBox "Fehler " & Err.Number & ": " & _
             Err.Description, vbCritical, _
             "modKap02.DAO_CheckFieldType"
  End Select
  DAO_CheckFieldType = False
  Resume HandleExit
End Function
ADOX-Variante

Beispiel:

Public Function ADO_CheckFieldType(pcnn As ADODB.Connection, _
                                   ByVal psTable As String, _
                                   ByVal psField As String) As Long
 
  On Error GoTo HandleErr
  Dim cat As New ADOX.Catalog
  cat.ActiveConnection = pcnn
  ADO_CheckFieldType = cat.Tables(psTable).Columns(psField).Type
 
HandleExit:
  If Not cat Is Nothing Then Set cat = Nothing
  Exit Function
 
HandleErr:
  Select Case Err.Number
    Case Else
      MsgBox "Fehler " & Err.Number & ": " & _
             Err.Description, vbCritical, _
             "modKap02.ADO_CheckFieldType"
  End Select
  ADO_CheckFieldType = False
  Resume HandleExit
End Function


Zurück Tabellen - Feldgröße | Inhalt | Tabellen - Neues Feld Weiter