Tabellen - Feldgröße

Stimmt die Feldgröße eines Textfeldes?

Wenn man die Größe eines Feldes vom Typ Text geändert hat sollte man vor einem Update bzw. einer Anpasse prüfen, ob die Größe bereits angepasst wurde. Die Nachfolgende Funktion prüft, ob die Feldgröße der übergebenen Größe entspricht. Ist des der Fall, wird True zurückgeliefert.

DAO-Variante

Beispiel:

Public Function DAO_TextFieldSize(pdbs As DAO.Database, _
                                  ByVal psTable As String, _
                                  ByVal psField As String, _
                                  ByVal piSize As Integer) As Boolean
 
  On Error GoTo HandleErr
  DAO_TextFieldSize = pdbs.TableDefs(psTable).Fields(psField).Size = piSize
 
HandleExit:
  Exit Function
 
HandleErr:
  Select Case Err.Number
    Case Else
      MsgBox "Fehler " & Err.Number & ": " & _
             Err.Description, vbCritical, _
             "modKap02.DAO_TextFieldSize"
  End Select
  DAO_TextFieldSize = False
  Resume HandleExit
End Function
ADOX-Variante

Beispiel:

Public Function ADO_TextFieldSize(pcnn As ADODB.Connection, _
                                  ByVal psTable As String, _
                                  ByVal psField As String, _
                                  ByVal piSize As Integer) As Boolean
 
  On Error GoTo HandleErr
  Dim cat As New ADOX.Catalog
  cat.ActiveConnection = pcnn
  ADO_TextFieldSize = cat.Tables(psTable).Columns(psField).DefinedSize = piSize
 
HandleExit:
  If Not cat Is Nothing Then Set cat = Nothing
  Exit Function
 
HandleErr:
  Select Case Err.Number
    Case Else
      MsgBox "Fehler " & Err.Number & ": " & _
             Err.Description, vbCritical, _
             "modKap02.ADO_TextFieldSize"
  End Select
  ADO_TextFieldSize = False
  Resume HandleExit
End Function


Zurück Tabellen - Feld vorhanden | Inhalt | Tabellen - Felddatentyp Weiter