Tipp 5.11 - Arbeitsspeicher

Wie kann ich den Gesamt- und verfügbaren Arbeitsspeicher ermitteln?

Mit dieser Funktion können Sie den Gesamt- und verfügbaren Arbeitsspeicher ermitteln. Kopieren Sie einfach nachfolgenden Quellcode in die Zwischenablage und fügen Sie anschließend den Inhalt der Zwischenablage in ein neues Modul ein. Die Aufrufparameter finden Sie im Quellcode beschrieben.

Api-AufrufeVerwendete Win32-Api-Aufrufe und Typen: GlobalMemoryStatus - MEMORYSTATUS

Beispiel:

Option Explicit
 
Public Type MEMORYSTATUS
  dwLength                    As Long
  dwMemoryLoad                As Long
  dwTotalPhys                 As Long
  dwAvailPhys                 As Long
  dwTotalPageFile             As Long
  dwAvailPageFile             As Long
  dwTotalVirtual              As Long
  dwAvailVirtual              As Long
End Type
 
Public Declare Sub GlobalMemoryStatus _
    Lib "kernel32" (lpBuffer As MEMORYSTATUS)
 
Public Sub GetMemoryData( _
           sTotalPhysical As String, _
           sTotalAvailable As String)
  '// -----------------------------------------------------
  '// Methode:   | Gesamt- und verfügbaren Arbeitsspeicher
  '//            | ermitteln
  '// -----------------------------------------------------
  '// Parameter: | sTotalPhysical  - Gesamtspeicher
  '//            | sTotalAvailable - verfügbarer Speicher
  '// -----------------------------------------------------
  '// Rückgabe:  | s.o.
  '// -----------------------------------------------------
  '// Autor:     | Stefan Kulpa
  '//            | EDV Innovation & Consulting - Dormagen
  '// -----------------------------------------------------
  Const csNUMFORMAT   As String = "###,###,###,###,###,###"
  Dim uMemory         As MEMORYSTATUS
 
  uMemory.dwLength = Len(uMemory)
  GlobalMemoryStatus uMemory
  sTotalPhysical = Format$(uMemory.dwTotalPhys, _
      csNUMFORMAT) + " Byte"
  sTotalAvailable = Format$(uMemory.dwAvailPhys, _
      csNUMFORMAT) + " Byte"
 
End Sub


Zurück Tipp 5.10 - Festplattenplatz | Inhalt | Tipp 5.12 - Auslagerungsspeicher Weiter