Tipp 6.4 - Long Registry-Schlüssel

Wie kann ich einen Registry-Schlüssel vom Typ Long ermitteln?

Mit dieser Funktion können Sie einen Registry-Schlüssel vom Typ Long ermitteln. Kopieren Sie einfach nachfolgenden Quellcode in die Zwischenablage und fügen Sie anschließend den Inhalt der Zwischenablage in ein neues Modul ein. Die Aufrufparameter finden Sie im Quellcode beschrieben.

Api-AufrufeVerwendete Win32-Api-Aufrufe und Typen: RegOpenKey, RegQueryValueExLong, RegCloseKey - REG_KEYS

Beispiel:

Option Explicit
 
Public Enum REG_KEYS
  HKEY_CLASSES_ROOT = &H80000000
  HKEY_CURRENT_USER = &H80000001
  HKEY_LOCAL_MACHINE = &H80000002
  HKEY_USERS = &H80000003
  HKEY_PERFORMANCE_DATA = &H80000004
  HKEY_CURRENT_CONFIG = &H80000005
  HKEY_DYN_DATA = &H80000006
End Enum
 
Public Const ERROR_SUCCESS As Long = 0&
 
Public Declare Function RegOpenKey _
    Lib "advapi32.dll" Alias _
    "RegOpenKeyA" _
    (ByVal hKey As Long, _
    ByVal lpSubKey As String, _
    phkResult As Long) As Long
Public Declare Function RegQueryValueExLong _
    Lib "advapi32.dll" Alias _
    "RegQueryValueExA" _
    (ByVal hKey As Long, _
    ByVal sValue As String, _
    ByVal lReserved As Long, _
    lType As Long, _
    lData As Long, _
    lcbData As Long) As Long
Public Declare Function RegCloseKey Lib "advapi32.dll" _
    (ByVal hKey As Long) As Long
 
Public Function GetSettingLong( _
                ByVal lKey As REG_KEYS, _
                ByVal sPath As String, _
                ByVal sValue As String, _
                Optional lDefault As Long = 0) As Long
  '// -----------------------------------------------------
  '// Methode:   | Ermittelt einen Longw. aus der Registry
  '// -----------------------------------------------------
  '// Parameter: | lKey - Übergeordneter Schlüssel
  '//            | sPath - Pfad des Schlüssels
  '//            | sValue - Name des Wertes
  '//            | lDefault - Standard Rückgabewert
  '// -----------------------------------------------------
  '// Rückgabe:  | Ermittelter Wert
  '// -----------------------------------------------------
  '// Autor:     | Stefan Kulpa
  '//            | EDV Innovation & Consulting - Dormagen
  '// -----------------------------------------------------
  '// Beispiel:  |?GetSettingLong(HKEY_LOCAL_MACHINE, _
  '//            |               "SOFTWARE" & _
  '//            |                App.CompanyName & "\" & _
  '//            |                App.EXEName, "Left")
  '// -----------------------------------------------------
  Const REG_DWORD     As Long = 4
  Dim lDataBufferSize As Long
  Dim lRegResult      As Long
  Dim lValueType      As Long
  Dim lCurKey         As Long
  Dim lBuffer         As Long
  GetSettingLong = lDefault
  lRegResult = RegOpenKey(lKey, sPath, lCurKey)
  lDataBufferSize = 4  '// 4 Bytes = 32 Bits (Long)
  lRegResult = RegQueryValueExLong(lCurKey, _
      sValue, _
      0&, _
      lValueType, _
      lBuffer, _
      lDataBufferSize)
  If lRegResult = ERROR_SUCCESS Then
    If lValueType = REG_DWORD Then GetSettingLong = lBuffer
  End If
  lRegResult = RegCloseKey(lCurKey)
 
End Function


Zurück Tipp 6.3 - Registry-Schlüssel-Wert entfernen | Inhalt | Tipp 6.5 - Long Registry-Schlüssel schreiben Weiter