Tipp 10.20 - BMI errechnen

Wie kann ich meinen Body-Mass-Index (BMI) errechnen?

Wer hätte es nicht gerne, das Idealgewicht? Seit einigen Jahren wird das Körpergewicht immer häufiger nach dem so genannten Body-Mass-Index (kurz BMI) bewertet. Der Body-Mass-Index ergibt sich aus Ihrem Körpergewicht und Ihrer Größe. Er wird zur weiteren Berechnung von Ideal- bzw. Zielgewicht benötigt. Dazu verwenden sie folgende Formel:

  • BMI = Körpergewicht in Kg / (Körpergröße in m * Körpergröße im m)

D.h., um den BMI zu errechnen, bilden Sie einfach das Quadrat Ihrer Körpergröße in Meter und dividieren Ihr Gewicht einfach durch diesen Wert. Kopieren Sie einfach nachfolgenden Quellcode in die Zwischenablage und fügen Sie anschließend den Inhalt der Zwischenablage in ein neues Modul ein. Die Aufrufparameter finden Sie im Quellcode beschrieben.

Beispiel:

'BMI errechnen
Public Function CalcBMI(plGeschlecht As Long, _
                        pdbGewicht As Double, _
                        pdbGroesse As Double) As String
  '// =====================================================
  '// Methode   | Errechnet den Body-Mass-Index
  '// -----------------------------------------------------
  '// Parameter | plGeschlecht - männlich = 1;weiblich = 2
  '               pdbGewicht   - Gewicht in Kg
  '               pdbGroesse   - Größe in m
  '// -----------------------------------------------------
  '// Rückgabe  | String = Errechneter Wert + Hinweistext
  '// -----------------------------------------------------
  '// Erstellt  | Stefan Kulpa
  '//           | EDV Innovation & Consulting - Dormagen
  '// -----------------------------------------------------
  '// Beispielaufruf im Debugfenster:
  '// MsgBox CalcBMI(2, 63, 1.72), vbInformation, "BMI"
  '// =====================================================
 
  Dim dbBMI As Double
 
  On Error GoTo CalcBMI_Err
 
  dbBMI = CDbl(Format(pdbGewicht / (pdbGroesse * pdbGroesse), "0.00"))
  CalcBMI = CheckBMI(plGeschlecht, dbBMI)
 
CalcBMI_Exit:
  On Error GoTo 0
  Exit Function
 
CalcBMI_Err:
  MsgBox "Fehler " & Err.Number & ": " & _
         Err.Description, vbCritical, _
         "modDiv.CalcBMI"
  Resume CalcBMI_Exit
End Function
 
Public Function CheckBMI(plGeschlecht As Long, _
                         pdbBMI As Double) As String
 
  '// =====================================================
  '// Methode   | Hilfsfunktion für die Berechnung des
  '               Body-Mass-Index
  '// -----------------------------------------------------
  '// Parameter | plGeschlecht - männlich = 1;weiblich = 2
  '               pdbBMI       - BMI-Wert
  '// -----------------------------------------------------
  '// Rückgabe  | String = Hinweistext
  '// -----------------------------------------------------
  '// Erstellt  | Stefan Kulpa
  '//           | EDV Innovation & Consulting - Dormagen
  '// =====================================================
 
  Dim lBMIFaktor As Long
 
  On Error GoTo CheckBMI_Err
 
  If pdbBMI < 30 Then
    ' Männlich
    If plGeschlecht = 1 Then
      Select Case pdbBMI
        Case Is < 20     ' Untergewicht
          lBMIFaktor = 1
        Case Is < 25     ' Normalgewicht
          lBMIFaktor = 2
        Case Else        ' Übergewicht
          lBMIFaktor = 3
      End Select
    Else
      ' Weiblich
      Select Case pdbBMI
        Case Is < 19     ' Untergewicht
          lBMIFaktor = 1
        Case Is < 24     ' Normalgewicht
          lBMIFaktor = 2
        Case Else        ' Übergewicht
          lBMIFaktor = 3
      End Select
    End If
  Else
    Select Case pdbBMI
      Case Is < 40       ' Adipositas
        lBMIFaktor = 4
      Case Is > 40       ' massive Adipositas
        lBMIFaktor = 5
    End Select
  End If
 
  Select Case lBMIFaktor
    Case 1
      CheckBMI = "BMI: " & pdbBMI & " = Untergewicht" & vbCrLf & vbCrLf & _
                 "Mit Ihrem momentanen Gewicht sind sie untergewichtig. " & vbCrLf & _
                 "Versuchen Sie mit einer gemächlichen Gewichtszunahme mindestens" & vbCrLf & _
                 "einen BMI von 19 zu erreichen."
    Case 2
      CheckBMI = "BMI: " & pdbBMI & " = Normalgewicht" & vbCrLf & vbCrLf & _
                 "Gratulation! Ihr BMI ist ideal! Versuchen Sie dieses" & vbCrLf & _
                 "Gewicht so lange wie möglich zu halten."
    Case Else
      Select Case lBMIFaktor
        Case 3
          CheckBMI = "BMI: " & pdbBMI & " = Übergewicht" & vbCrLf & vbCrLf
        Case 4
          CheckBMI = "BMI: " & pdbBMI & " = Adipositas" & vbCrLf & vbCrLf
        Case 5
          CheckBMI = "BMI: " & pdbBMI & " = massive Adipositas" & vbCrLf & vbCrLf
      End Select
      CheckBMI = CheckBMI & "Mit Ihrem momentanen Gewicht sind Sie übergewichtig." & vbCrLf & _
                 "Versuchen Sie auf jeden Fall, abzunehmen - am besten" & vbCrLf & _
                 "unter ärztlicher Kontrolle."
  End Select
 
CheckBMI_Exit:
   On Error GoTo 0
   Exit Function
 
CheckBMI_Err:
  MsgBox "Fehler " & Err.Number & ": " & _
         Err.Description, vbCritical, _
         "modDiv.CheckBMI"
  Resume CheckBMI_Exit
End Function

Die nachfolgende Tabelle zeigt Ihnen die empfohlenen BMI-Werte nach DGE, Ernährungsbericht 1992:

BMI-Klassifikation
Klassifikation männlich weiblich
Untergewicht < 20 < 19
Normalgewicht 20 - 25 19 - 24
Übergewicht 25 - 30 24 - 30
Adipositas 30 - 40 30 - 40
massive Adipositas > 40 > 40

Der normale BMI-Wert liegt bei Frauen zwischen 19 und 24, bei Männern zwischen 20 und 25. Bei Männern und Frauen ab 65 Jahren gilt ein BMI zwischen 24 und 29 als Normalgewicht. Doch bei all den Formeln muss beachtet werden, dass natürlich auch noch andere Faktoren z.B. Muskelmasse etc.pp. eine Rolle spielen - und nichts desto trotz ist das Wohlfühlgewicht das wichtigste!



Zurück Tipp 10.19 - Negative Werte | Inhalt | Weiter