Tipp 2.1 - Alter errechnen

Wie kann ich das Alter aus einem Datum errechnen?

Mit dieser Funktion können Sie das Alter anhand eines Datums ermitteln. Kopieren Sie einfach nachfolgenden Quellcode in die Zwischenablage und fügen Sie anschließend den Inhalt der Zwischenablage in ein neues Modul ein. Die Aufrufparameter finden Sie im Quellcode beschrieben.

Beispiel:

 
 
Option Explicit
 
Public Function Age( _
                dtBirthday As Date, _
                Optional lWeeks As Long) _
                As Long
  '// -----------------------------------------------------
  '// Methode:   | Ermittelt das Alter in Jahren und
  '//            | optional in Wochen
  '// -----------------------------------------------------
  '// Parameter: | dtBirthday - gültiges Geburtsdatum
  '//            | lWeeks     - optionale Rückgabevariable
  '// -----------------------------------------------------
  '// Rückgabe:  | das Alter in Jahren;
  '//            | optional in Wochen (lWeeks)
  '// -----------------------------------------------------
  '// Autor:     | Stefan Kulpa
  '//            | EDV Innovation & Consulting - Dormagen
  '// -----------------------------------------------------
 
  On Error GoTo Err_Age
  If Day(dtBirthday) <= Day(Now) Then
    lWeeks = DateDiff("w", dtBirthday, Now)
  Else
    lWeeks = DateDiff("w", dtBirthday, Now) - 1
  End If
  Age = Year(Now) - Year(dtBirthday) + _
      (DateSerial(Year(Now), _
      Month(dtBirthday), _
      Day(dtBirthday)) > Now)
Exit_Age:
  Exit Function
Err_Age:
  Age = 0
  lWeeks = 0
  Resume Exit_Age
 
End Function


Zurück | Inhalt | Tipp 2.2 - Resttage berechnen Weiter