Tipp 2.13 - Eigenschaftenfenster ausblenden

Wie kann ich verhindern, dass das Eigenschaftsfenster in der Formularansicht geöffnet wird.

Wenn Sie ein Formular ab Microsoft Access 2000 speichern, während das Eigenschaftsfenster geöffnet ist, wird beim nächsten Öffnen des Formulars in der Formularansicht auch das Eigenschaftsfenster angezeigt. Über die Formulareigenschaft: Entwurfsänderung zulassen (AllowDesignChanges) steuern Sie diesen Vorgang. Falls Sie versuchen, die Eigenschaft per Code zusetzen (FormName.AllowDesignChanges = False) berücksichtigen Sie bitte, dass diese Möglichkeit nur im Formularentwurf zur Verfügung steht. Am besten Stellen Sie die Eigenschaft direkt beim ersten Erstellen Ihres Formulars ein:

  1. Formular aktivierenÖffnen Sie das Formular in der Entwurfsansicht
  2. Achten Sie darauf, dass das Formular im Allgemeinen aktiviert ist.
  3. Klicken Sie in das Menü Ansicht – Eigenschaften (Alt+Enter) und klicken Sie auf die Registerkarte Andere.
  4. Setzen Sie die Eigenschaft: Entwurfsänderungen zulassen auf Nur Entwurfsansicht.

Leider müssen Sie diese Eigenschaft grundsätzlich für jedes Formular hinterlegen, da diesbezüglich keine globale Einstellmöglichkeit vorhanden ist. Alternativ schreiben Sie sich eine kleine Routine, die Ihnen diese Arbeit abnimmt:

Beispiel:

Public Function HidePropWindow() As Boolean
  '// =====================================================
  '// Methode   | Blendet das Eigenschaftenfenster in
  '               der Formularansicht aus
  '// -----------------------------------------------------
  '// Rückgabe  | Boolean - Erfolgreich ja/nein
  '// -----------------------------------------------------
  '// Erstellt  | Manuela Kulpa
  '//           | EDV Innovation & Consulting - Dormagen
  '// -----------------------------------------------------
  '// Beispielaufruf:
  '// im Direktfenster: ?HidePropWindow
  '// =====================================================
 
  Dim frm As Form
  Dim sobj As String
  Dim obj As AccessObject
 
  On Error GoTo HidePropWindow_Error
 
  ' Schleife über alle Formulare
  For Each obj In CurrentProject.AllForms
    ' Formularname ermitteln
    sobj = obj.Name
    ' Formular im Entwurf öffnen
    DoCmd.OpenForm sobj, acDesign
    ' Formularobjekt setzen
    Set frm = Forms(sobj)
    ' Eigenschaftenfenster ausschalten
    If frm.AllowDesignChanges = True Then
      frm.AllowDesignChanges = False
      ' Änderung speichern
      DoCmd.Save acForm, sobj
    End If
    ' Formular schließen
    DoCmd.Close acForm, sobj
    Set frm = Nothing
  Next obj
 
  HidePropWindow = True
 
HidePropWindow_Exit:
  On Error GoTo 0
  Exit Function
 
HidePropWindow_Error:
  HidePropWindow = False
  Select Case Err.Number
    Case 29068
      Resume Next
    Case Else
      MsgBox "Fehler " & Err.Number & ": " & _
             Err.Description, vbCritical, _
             "modVersion23.HidePropWindow"
  End Select
  Resume HidePropWindow_Exit
 
End Function


Zurück Tipp 2.12 - Systemmenü ein/aus | Inhalt | Tipp 2.14 - Mehrere Controls auf einmal Weiter