Tipp 3.6 - Berichte in String

Wie kann ich einem String die Namen aller Berichte der aktuellen Datenbank übergeben?

Mit dieser Funktion können Sie einem String die Namen aller Berichte der aktuellen Datenbank übergeben. Kopieren Sie einfach nachfolgenden Quellcode in die Zwischenablage und fügen Sie anschließend den Inhalt der Zwischenablage in ein neues Modul ein. Die Aufrufparameter finden Sie im Quellcode beschrieben.

Beispiel:

Public Function A2XRptNamesToString(psIn As String, _
                                    psDelimit As String) _
                                    As Integer
  '// =====================================================
  '// Methode   | Übergibt einem String die Namen aller
  '//           | Berichte in der aktuellen DB
  '// -----------------------------------------------------
  '// Parameter | psIn      - Leerstring
  '//           | psDelimit - Trennzeichen
  '// -----------------------------------------------------
  '// Rückgabe  | Integer - Anzahl Berichte
  '// -----------------------------------------------------
  '// Erstellt  | Manuela Kulpa
  '//           | EDV Innovation & Consulting - Dormagen
  '// -----------------------------------------------------
  '// Beispielaufruf:
  '// Dim iCount As Integer
  '// Dim sReports As String
  '// iCount = A2XRptNamesToString(sReports, ", ")
  '// Debug.Print "Berichte: " & sReports
  '// =====================================================
 
  ' Verweis auf DAO 3.6 Object Library muss gesetzt sein!
  Dim dbs As DAO.Database
  Dim con As Container
  Dim doc As Document
  Dim iCounter As Integer
  Dim iCount As Integer
  Dim sName As String
 
  On Error GoTo A2XRptNamesToString_Error
 
  Set dbs = CurrentDb()
  Set con = dbs.Containers("reports")
 
  iCount = con.Documents.Count
 
  For Each doc In con.Documents
    sName = doc.Name
    psIn = psIn & sName
 
    If iCounter < iCount - 1 Then
      psIn = psIn & psDelimit
    End If
 
  Next doc
 
  A2XRptNamesToString = iCount
 
A2XRptNamesToString_Exit:
  On Error GoTo 0
  Exit Function
 
A2XRptNamesToString_Error:
  Select Case Err.Number
  Case Else
    MsgBox "Fehler " & Err.Number & ": " & _
           Err.Description, vbCritical, _
           "modRpt.A2XRptNamesToString"
  End Select
  Resume A2XRptNamesToString_Exit
 
End Function


Zurück Tipp 3.5 - Berichte in Array | Inhalt | Tipp 3.7 - Bericht schließen Weiter