Hinweis: Durch spezielle Anweisungen können Sie diese Funktion erst ab Access 2000 einsetzen.

Beispiel:

Option Explicit
 
Public Enum eCurrentType
  A2XName = 0
  A2XPath = 1
  A2XNamePath = 2
End Enum
 
Public Function GetA2XCurrentDbInfo( _
                peType As eCurrentType) _
                As String
  '// =====================================================
  '// Methode   | Ermittelt den Namen und den Pfad der
  '//           | aktuellen DB. Alternativ kann man nur
  '//           | den Namen oder den Pfad ermitteln lassen
  '// -----------------------------------------------------
  '// Parameter | pEType - Angabe des Typen
  '//           |          Das Enum eCurrentType sollte
  '//           |          vorab auf Modulebene deklariert
  '//           |          sein!
  '// -----------------------------------------------------
  '// Rückgabe  | String - je nach Auswahl s.o.
  '// -----------------------------------------------------
  '// Erstellt  | Manuela Kulpa
  '//           | EDV Innovation & Consulting - Dormagen
  '// =====================================================
 
  On Error GoTo HandleErr
  Dim sDBName As String
 
  sDBName = CurrentDb.Name
 
  Select Case peType
    Case A2XName
      sDBName = Mid(sDBName, _
                    InStrRev(StringCheck:=sDBName, _
                             StringMatch:="\") + 1)
    Case A2XPath
      sDBName = Left(sDBName, _
                     InStrRev(StringCheck:=sDBName, _
                              StringMatch:="\"))
    Case A2XNamePath
      sDBName = sDBName
  End Select
 
  GetA2XCurrentDbInfo = sDBName
 
HandleExit:
  Exit Function
 
HandleErr:
  Select Case Err.Number
    Case Else
      MsgBox "Fehler " & Err.Number & ": " & _
             Err.Description, vbCritical, _
             "basInfo.GetA2XCurrentDbInfo"
  End Select
  Resume HandleExit
End Function